当前位置:主页 > 编程教学 > 正文

ass2srt.vbs(ass/ssa批量转换srt的脚本)

09-28 编程教学

iPad中的OPlayer只支持srt格式的字幕,而动画一般使用的是ass/ssa格式的字幕,所以需要将ass/ssa批量转换srt。

Google了一下,在《ass2srt[ass/ssa批量转换srt]》中找到一个ass2srt.wsf脚本,内容如下:

<job id="ass2srt">
  <script language="JScript">
  cInput="unicode";  // You can find them from:
  cOutput="utf-8";  // HKEY_CLASSES_ROOT\MIME\Database\Charset
  function rrr(){
    re = /Dialogue: [^,.]*[0-9]*,([1-9]?[0-9]*:[0-9]*:[0-9]*.[0-9]*),([1-9]?[0-9]*:[0-9]*:[0-9]*.[0-9]*),[^,.]*,[^,.]*,[0-9]*,[0-9]*,[0-9]*,[^,.]*,(.*)/gi;
    rv = ss.match(re);
    t1 = RegExp.$1;
    t2 = RegExp.$2;
    t3 = RegExp.$3;
    rg = /\{[^}.]*(\\pos\([0-9]*,[0-9]*\))[^}.]*}/gi;
    t3 = t3.replace(rg,"$1" + "}"); 
    rg =/\{[^}.]*}/gi;
    t3 = t3.replace(rg,"");
    rg =/(\\pos\([0-9]*,[0-9]*\)})/gi;
    t3 = t3.replace(rg,"{" + "$1"); 
    }
  </Script>
  <script language="VBScript">
  set ad=CreateObject("adodb.stream")
  set af=CreateObject("adodb.stream")
  set ass=CreateObject("adodb.stream")
  ad.open
  af.open
  ass.open
  ad.Charset=cInput
  af.Charset=cOutput
  ass.Charset=cOutput
  Set objArgs = WScript.Arguments
  For I = 0 to objArgs.Count - 1
    ad.LoadFromFile(objArgs(I))
    z=0
    gg=left(objArgs(I),len(objArgs(I))-3)&"srt"
    Do While ad.eos <> True
      ss =ad.ReadText(-2)
      if left(ss,8)="Dialogue" then 
        ss=replace(ss,",,",",d,")
        rrr
        t3=replace(t3,"\n",vbcrlf)
        t3=replace(t3,"\N",vbcrlf)
        z=z+1
        af.writetext z,1
        af.writetext t1 & " --> " & t2,1
        af.writetext t3 & vbcrlf & vbcrlf
      else 
        ass.writetext ss,1
      end if
    Loop
    af.savetofile gg,2
    ass.savetofile gg&".style",2
  Next
  if i=0 then 
    msgbox "Please drag files to me!",,"Error!"
  else
    msgbox "Converted "&i&" file(s).",,"All Over!"
  end if
  </Script>
</job>

Windows 脚本 (.wsf) 文件是一个包含可扩展标记语言(XML)代码的文本文档,它结合了若干功能,提高了脚本编程的灵活性。由于 Windows 脚本文件并不局限于特定的引擎,它们能够包含所有遵循 ActiveX(R)规范的脚本引擎的脚本。

上面的脚本文件同时包含了JScript和VBScript的代码。问题在于,有这个必要么?单纯用JScript或者VBScript都可以实现,为什么要混用不同的语言呢?JScript在代码中的作用仅仅是正则表达式而已,一个合理的推断是作者不会VBScript的正则表达式,或者嫌VBScript的正则表达式太麻烦。就算撇开语言混杂不说,上面代码的风格实在是不敢恭维。

下面是我写的ass2srt.vbs,也许比上面的代码好一点点罢。

Option Explicit
Const Encoding = "unicode" 'assume unicode

'Author: Demon
'Website: http://demon.tw
'Date: 2012/6/16

Dim shell, folder, fso, ext, i, args
Set shell = CreateObject("Shell.Application")
Set fso = CreateObject("scripting.filesystemobject")
Set args = WScript.Arguments

If args.Count = 0 Then
  Set folder = shell.BrowseForFolder(0, "请选择ASS字幕所在的文件夹", 1)
  If folder Is Nothing Then WScript.Quit
  For Each i In fso.GetFolder(folder.Self.Path).Files
    ext = LCase(fso.GetExtensionName(i.Path))
    If ext = "ass" Or ext = "ssa" Then
      ASS2SRT i.Path, Encoding
    End If
  Next
Else
  For i = 0 To args.Count - 1
    ASS2SRT args(i), Encoding
  Next
End If

MsgBox CInt(i) & " file(s) Converted!", vbInformation

Function ASS2SRT(path, charset)
  Const adTypeText = 2
  Const adReadLine = -2
  Const adSaveCreateOverWrite = 2
  Dim ass, srt, re, str, arr, s, e, t, i
  
  Set ass = CreateObject("ADODB.Stream")
  Set srt = CreateObject("ADODB.Stream")
  Set re = New RegExp
  
  re.Global = True
  re.IgnoreCase = True
  re.Pattern = "\{.*?\}"
  
  ass.Type = adTypeText
  ass.Charset = charset
  ass.Open
  ass.LoadFromFile path
  
  srt.Type = adTypeText
  srt.Charset = "utf-8"
  srt.Open
  
  i = 0
  
  Do Until ass.EOS
    str = ass.ReadText(adReadLine)
    If Left(str, 8) = "Dialogue" Then
      i = i + 1
      arr = Split(str, ",", 10)
      s = "0" & arr(1) & "0" 'Start time
      e = "0" & arr(2) & "0" 'End time
      t = arr(9) 'Text
      s = Replace(s, ".", ",")
      e = Replace(e, ".", ",")
      t = re.Replace(t, "")
      t = Replace(t, "\n", vbCrLf)
      t = Replace(t, "\N", vbCrLf)
      srt.WriteText i & vbCrLf
      srt.WriteText s & " --> " & e & vbCrLf
      srt.WriteText t & vbCrLf & vbCrLf
    End If
  Loop
  
  path = Left(path, Len(path) - 3) & "srt"
  srt.SaveToFile path, adSaveCreateOverWrite
End Function

把上面代码保存为ass2srt.vbs,然后将需要转换的ass/ssa字幕拖动到ass2srt.vbs脚本上即可。如果需要批量转换的ass/ssa字幕比较多,可以先把它们放到同一个文件夹里,然后直接双击运行ass2srt.vbs,选择字幕所在的文件夹即可。

原文:http://demon.tw/my-work/ass2srt.html


相关拓展:大切诺基SRT8外观设计

2012款大切诺基SRT8(20张)

外观方面,新款大切诺基的变化比较明显。新车的前进气格栅由连体式七孔设计改为独立式七孔设计。前大灯也采用了与全新克莱斯勒300相似的设计理念并配有日间行车灯。保险杠也采用了大开口的新样式,使车头看起来更加时尚且富有力量感。

大切诺基SRT8较普通版降低2.54厘米的车身,配合个性化的空气动力学外包围,动感且个性十足;一体式前下方隔栅喷涂有亮光黑漆配以全新的SRT专用车身颜色轮眉和侧梁装饰条全新的LED多功能昼间行车灯,令Jeep大切诺基SRT8的前脸更显独一无二;肌肉感实足的镀铬闪亮银20"五幅镂空轮圈;拥有独特黑屏背景的车身颜色前隔栅和镀铬面板也令汽车平添了许多夺人气势。

车身下方导流板集成了制动通风导管,改善气流的同时,也可提升冷却性能。全新的前端设计还包括新颖精致的引擎盖,后者带有两个黑色散热孔,可增强发动机的冷却效果;在汽车的后侧,全新的电动尾门扰流器降低了阻力,同时也增加了高速行驶的下压力;装载4英寸排气管的双运动排气系统也是2012大切诺基SRT8的全新功能。

title

带有黑色过滤保护网的双引擎盖散热孔,提升发动机的性能,使大切诺基SRT8的的品质得以凸显。匹配20英寸轮圈和20英寸倍耐力All-Season Performance 轮胎P295/45ZR20,胎面更宽,扁平比更小的轮胎,提供更佳的抓地力。五种可选驾乘活动采用自适应悬挂调整,乘坐平稳舒适,可自动适应任何路况;配备了顶级跑车专用的红色Brembo制动器,前6活塞和后4活塞制动卡钳,四角均有通风转子,大小为15英寸(前)和13.8英寸(后),同级别最强制动效果,远远优于竞争对手。


seo达人二飞
红德智库的网站技术.擅长网站建设,seo(百度关键词排名). qq:379564208
个人seo案例:配资|配资|股票配资|seo教程

SEO以及网站程序制作业务

seo业务:seo就是搜索引擎优化服务。简单说就是让网站在百度搜索中有个好的排名。我们根据搜索的关键词进行评估报价。

网站制作业务:我们承接中高端网站建设,程序开发。具体根据需求进行报价。我们力求以性价比最高的方案让您满意。